blob: 00a0d939d7499a1fab49aee5a96f900df551d925 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
# Copyright 2022-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit go-module shell-completion
DESCRIPTION="Distributed, offline-first bug tracker embedded in git"
HOMEPAGE="https://github.com/git-bug/git-bug"
SRC_URI="https://github.com/git-bug/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
SRC_URI+=" https://github.com/gentoo-golang-dist/git-bug/releases/download/v${PV}/git-bug-${PV}-vendor.tar.xz"
LICENSE="GPL-3"
# Dependent licenses
LICENSE+=" Apache-2.0 BSD-2 BSD ISC MIT MPL-2.0 Unlicense"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
BDEPEND=">=dev-lang/go-1.26.0"
QA_PRESTRIPPED=usr/bin/git-bug
src_compile() {
ego generate
local ego_build_args=(
-ldflags "-s -w -X github.com/git-bug/git-bug/commands.GitLastTag=${PV} -X github.com/git-bug/git-bug/commands.GitExactTag=${PV}"
-o ${PN}
)
ego build "${ego_build_args[@]}"
}
src_test() {
# TestValidateProject fails with FEATURES=network-sandbox
CI=true ego test -v ./... -skip "TestValidateProject"
}
src_install() {
dobin git-bug
doman doc/man/*.1
dobashcomp misc/completion/bash/git-bug
newzshcomp misc/completion/zsh/git-bug _git-bug
newfishcomp misc/completion/fish/git-bug git-bug.fish
}
|
